1 files changed, 211 insertions, 0 deletions
diff --git a/net-p2p/monero/monero-0.17.3.0.ebuild b/net-p2p/monero/monero-0.17.3.0.ebuild
new file mode 100644
index 00000000..0a45c1bf
--- /dev/null
+++ b/net-p2p/monero/monero-0.17.3.0.ebuild
@@ -0,0 +1,211 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+MONERO_GUI_PV=0.17.3.0
+
+PYTHON_COMPAT=( python{3_8,3_9} )
+CMAKE_MAKEFILE_GENERATOR="emake"
+inherit git-r3 cmake flag-o-matic toolchain-funcs python-any-r1 systemd
+
+DESCRIPTION="Secure, private, untraceable cryptocurrency"
+HOMEPAGE="https://getmonero.org"
+
+EGIT_REPO_URI="https://github.com/monero-project/${PN}.git"
+EGIT_COMMIT="v${PV}"
+EGIT_COMMIT_GUI="v${MONERO_GUI_PV}"
+EGIT_SUBMODULES=( external/trezor-common external/supercop external/quirc )
+
+LICENSE="NEWLIB"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm64"
+CPU_FLAGS="cpu_flags_arm_aes cpu_flags_x86_aes"
+IUSE="doc qt5 nls readline smartcard ${CPU_FLAGS}"
+
+RDEPEND="net-dns/unbound:=[threads]
+	>=dev-libs/randomx-1.1.9:=
+	net-libs/miniupnpc:=
+	dev-libs/openssl:0
+	|| (
+		>=dev-libs/boost-1.62:=[icu,nls]
+		>=dev-libs/boost-1.62:=[icu,threads,nls]
+	)
+	net-libs/zeromq:=[sodium]
+	dev-libs/rapidjson:=
+	readline? ( sys-libs/readline:= )
+	smartcard? (
+		dev-libs/hidapi:=
+		virtual/libusb:=
+		virtual/libudev:=
+		dev-libs/protobuf:=
+	)
+	qt5? (
+		dev-qt/qtconcurrent:5
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtdeclarative:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtsvg:5
+		dev-qt/qtxmlpatterns:5[qml]
+		dev-qt/qtwidgets:5
+		dev-qt/qtmultimedia:5
+		dev-qt/qtquickcontrols:5
+		dev-qt/qtquickcontrols2:5
+		dev-qt/qtgraphicaleffects:5
+		dev-libs/libgcrypt:=
+		media-fonts/fontawesome[ttf]
+	)
+	acct-user/monero
+	acct-group/monero"
+DEPEND="${RDEPEND}
+	nls? ( dev-qt/qtchooser )"
+BDEPEND="${PYTHON_DEPS}
+	doc? (
+		media-gfx/graphviz
+		app-doc/doxygen:0
+	)
+	qt5? ( dev-qt/linguist-tools:5 )
+	smartcard? ( $(python_gen_any_dep 'dev-python/protobuf-python[${PYTHON_USEDEP}]') )"
+
+PATCHES_MONERO=(
+	"${FILESDIR}/monero-${PV}-Drop-in-tree-miniupnpc.patch"
+	"${FILESDIR}/monero-${PV}-Use-gentoo-versioning.patch"
+	"${FILESDIR}/monero-${PV}-Do-not-install-trezor-dep-libs.patch"
+	"${FILESDIR}/monero-${PV}-Use-gentoo-dev-libs-randomx.patch"
+	"${FILESDIR}/monero-${PV}-translations-use-host-compiler.patch"
+)
+
+PATCHES_MONERO_GUI=(
+	"${FILESDIR}/monero-gui-${PV}-cmake-use-gentoo-versioning.patch"
+)
+
+CMAKE_BUILD_TYPE=Release
+
+src_unpack() {
+	git-r3_src_unpack
+
+	if use qt5 ; then
+		git-r3_fetch "https://github.com/monero-project/${PN}-gui.git" "${EGIT_COMMIT_GUI}"
+		git-r3_checkout "https://github.com/monero-project/${PN}-gui.git" "${WORKDIR}/monero-gui-${PV}"
+
+		rm -rf "${WORKDIR}/monero-gui-${PV}/monero" || die
+		ln -snf "${WORKDIR}/monero-${PV}" "${WORKDIR}/monero-gui-${PV}/monero" || die
+	fi
+}
+
+src_prepare() {
+	export AR=$(tc-getAR)
+	export CC=$(tc-getCC)
+	export CXX=$(tc-getCXX)
+	tc-export_build_env BUILD_C{C,XX}
+
+	append-cflags -DUSE_EXTRA_EC_CERT
+	append-cxxflags -DUSE_EXTRA_EC_CERT
+
+	CMAKE_USE_DIR="${WORKDIR}/monero-${PV}"
+	BUILD_DIR="${WORKDIR}/monero-${PV}_build"
+	S="${CMAKE_USE_DIR}" PATCHES="${PATCHES_MONERO[@]}" cmake_src_prepare
+
+	if use qt5 ; then
+		CMAKE_USE_DIR="${WORKDIR}/monero-gui-${PV}"
+		BUILD_DIR="${WORKDIR}/monero-gui-${PV}_build"
+		S="${CMAKE_USE_DIR}" PATCHES="${PATCHES_MONERO_GUI[@]}" cmake_src_prepare
+	fi
+}
+
+src_configure() {
+	local mycmakeargs
+	local cmakeargs_monero=(
+		-DBUILD_TAG="$(tc-arch)"
+		-DUSE_CCACHE=OFF
+		-DPYTHON_EXECUTABLE="${PYTHON}"
+		-DBUILD_DOCUMENTATION="$(usex doc ON OFF)"
+		-DBUILD_TESTS=OFF
+		-DCOVERAGE=OFF
+		-DUSE_READLINE="$(usex readline ON OFF)"
+		-DBUILD_GUI_DEPS="$(usex qt5 ON OFF)"
+		-DINSTALL_VENDORED_LIBUNBOUND=OFF
+		-DBUILD_SHARED_LIBS=OFF
+		-DMANUAL_SUBMODULES=ON
+	)
+
+	if use cpu_flags_arm_aes || use cpu_flags_x86_aes ; then
+		cmakeargs_monero+=( -DNO_AES=OFF )
+	else
+		cmakeargs_monero+=( -DNO_AES=ON )
+	fi
+
+	if use elibc_musl ; then
+		# https://github.com/monero-project/monero/issues/2030
+		cmakeargs_monero+=( -DSTACK_TRACE=OFF )
+	fi
+
+	local cmakeargs_monerogui=(
+		"${cmakeargs_monero[@]}"
+		-DUSE_DEVICE_TREZOR="$(usex smartcard ON OFF)"
+		-DWITH_SCANNER=ON
+		-DDEV_MODE=OFF
+	)
+
+	export DATABASE="lmdb"
+	export DEVELOPER_LOCAL_TOOLS=0
+	export DEVELOPER_LIBUNBOUND_OLD=0
+
+	cat > "${WORKDIR}/monero-${PV}_build/translations.cmake" <<- _EOF_ || die
+		SET (CMAKE_C_COMPILER "${BUILD_CC}")
+		SET (CMAKE_C_FLAGS "${BUILD_CFLAGS}")
+		SET (CMAKE_CXX_COMPILER "${BUILD_CXX}")
+		SET (CMAKE_CXX_FLAGS "${BUILD_CXXFLAGS}")
+		SET (CMAKE_EXE_LINKER_FLAGS "${BUILD_LDFLAGS}")
+		SET (CMAKE_MODULE_LINKER_FLAGS "${BUILD_LDFLAGS}")
+		SET (CMAKE_SHARED_LINKER_FLAGS "${BUILD_LDFLAGS}")
+_EOF_
+
+	CMAKE_USE_DIR="${WORKDIR}/monero-${PV}"
+	BUILD_DIR="${WORKDIR}/monero-${PV}_build"
+	mycmakeargs=( ${cmakeargs_monero[@]} )
+	cmake_src_configure
+
+	if use qt5 ; then
+		mkdir -p "${WORKDIR}/monero-gui-${PV}_build/monero" || die
+		cp "${WORKDIR}/monero-${PV}_build/translations.cmake" "${WORKDIR}/monero-gui-${PV}_build/monero/translations.cmake" || die
+
+		CMAKE_USE_DIR="${WORKDIR}/monero-gui-${PV}"
+		BUILD_DIR="${WORKDIR}/monero-gui-${PV}_build"
+		mycmakeargs=( ${cmakeargs_monerogui[@]} )
+		cmake_src_configure
+	fi
+}
+
+src_compile() {
+	CMAKE_USE_DIR="${WORKDIR}/monero-${PV}"
+	BUILD_DIR="${WORKDIR}/monero-${PV}_build"
+	cmake_src_compile
+
+	if use qt5 ; then
+		CMAKE_USE_DIR="${WORKDIR}/monero-gui-${PV}"
+		BUILD_DIR="${WORKDIR}/monero-gui-${PV}_build"
+		cmake_src_compile
+	fi
+}
+
+src_install() {
+	CMAKE_USE_DIR="${WORKDIR}/monero-${PV}"
+	BUILD_DIR="${WORKDIR}/monero-${PV}_build"
+	cmake_src_install
+
+	if use qt5 ; then
+		CMAKE_USE_DIR="${WORKDIR}/monero-gui-${PV}"
+		BUILD_DIR="${WORKDIR}/monero-gui-${PV}_build"
+		cmake_src_install
+	fi
+
+	rm -rf "${ED}/usr/include" || die
+	rm -rf "${ED}/usr/lib" || die
+
+	insinto /etc
+	doins utils/conf/monerod.conf
+
+	newinitd "${FILESDIR}/monerod.initd" monerod
+	systemd_dounit utils/systemd/monerod.service
+}