1 files changed, 0 insertions, 200 deletions
diff --git a/net-p2p/monero/monero-0.17.1.1.ebuild b/net-p2p/monero/monero-0.17.1.1.ebuild
deleted file mode 100644
index da8cca4c..00000000
--- a/net-p2p/monero/monero-0.17.1.1.ebuild
+++ /dev/null
@@ -1,200 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python{3_7,3_8,3_9} )
-CMAKE_MAKEFILE_GENERATOR="emake"
-inherit git-r3 cmake flag-o-matic toolchain-funcs python-single-r1 systemd
-
-DESCRIPTION="Secure, private, untraceable cryptocurrency"
-HOMEPAGE="https://getmonero.org"
-
-EGIT_REPO_URI="https://github.com/monero-project/${PN}.git"
-EGIT_COMMIT="v${PV}"
-EGIT_SUBMODULES=( external/trezor-common external/supercop )
-
-LICENSE="NEWLIB"
-SLOT="0/${PV}"
-KEYWORDS="~amd64"
-CPU_FLAGS="cpu_flags_arm_aes cpu_flags_x86_aes"
-IUSE="doc qt5 nls readline smartcard ${CPU_FLAGS}"
-
-RDEPEND="net-dns/unbound:=[threads]
-	>=dev-libs/randomx-1.1.6:=
-	net-libs/miniupnpc:=
-	dev-libs/openssl:0
-	>=dev-libs/boost-1.62:=[icu,threads,nls]
-	net-libs/zeromq:=[sodium]
-	dev-libs/rapidjson:=
-	readline? ( sys-libs/readline:= )
-	smartcard? (
-		dev-libs/hidapi:=
-		virtual/libusb:=
-		virtual/libudev:=
-		dev-libs/protobuf:=
-		$(python_gen_cond_dep 'dev-python/protobuf-python:=[${PYTHON_MULTI_USEDEP}]')
-	)
-	qt5? (
-		dev-qt/qtconcurrent:5
-		dev-qt/qtcore:5
-		dev-qt/qtgui:5
-		dev-qt/qtdeclarative:5
-		dev-qt/qtnetwork:5
-		dev-qt/qtsvg:5
-		dev-qt/qtxmlpatterns:5[qml]
-		dev-qt/qtwidgets:5
-		dev-qt/qtmultimedia:5
-		dev-qt/qtquickcontrols:5
-		dev-qt/qtquickcontrols2:5
-		dev-qt/qtgraphicaleffects:5
-		dev-libs/hidapi:=
-		media-gfx/zbar[jpeg,v4l]
-		media-fonts/fontawesome[ttf]
-	)
-	acct-user/monero
-	acct-group/monero"
-DEPEND="${PYTHON_DEPS}
-	doc? (
-		media-gfx/graphviz
-		app-doc/doxygen:0
-	)
-	nls? ( dev-qt/qtchooser )
-	qt5? ( dev-qt/linguist-tools:5 )
-	${RDEPEND}"
-
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-
-PATCHES_MONERO=(
-	"${FILESDIR}/monero-${PV}-Drop-in-tree-miniupnpc.patch"
-	"${FILESDIR}/monero-${PV}-Use-gentoo-versioning.patch"
-	"${FILESDIR}/monero-${PV}-Do-not-install-trezor-dep-libs.patch"
-	"${FILESDIR}/monero-${PV}-Use-gentoo-dev-libs-randomx.patch"
-	"${FILESDIR}/monero-${PV}-translations-use-host-compiler.patch"
-)
-
-PATCHES_MONERO_GUI=(
-	"${FILESDIR}/monero-gui-${PV}-cmake-remove-Werror.patch"
-	"${FILESDIR}/monero-gui-${PV}-cmake-use-gentoo-versioning.patch"
-)
-
-CMAKE_BUILD_TYPE=Release
-
-src_unpack() {
-	git-r3_src_unpack
-
-	if use qt5 ; then
-		git-r3_fetch "https://github.com/monero-project/${PN}-gui.git" "${EGIT_COMMIT}"
-		git-r3_checkout "https://github.com/monero-project/${PN}-gui.git" "${WORKDIR}/monero-gui-${PV}"
-
-		rm -rf "${WORKDIR}/monero-gui-${PV}/monero" || die
-		ln -snf "${WORKDIR}/monero-${PV}" "${WORKDIR}/monero-gui-${PV}/monero" || die
-	fi
-}
-
-src_prepare() {
-	export AR=$(tc-getAR)
-	export CC=$(tc-getCC)
-	export CXX=$(tc-getCXX)
-	tc-export_build_env BUILD_C{C,XX}
-
-	append-cflags -DUSE_EXTRA_EC_CERT
-	append-cxxflags -DUSE_EXTRA_EC_CERT
-
-	CMAKE_USE_DIR="${WORKDIR}/monero-${PV}"
-	BUILD_DIR="${WORKDIR}/monero-${PV}_build"
-	S="${CMAKE_USE_DIR}" PATCHES="${PATCHES_MONERO[@]}" cmake_src_prepare
-
-	if use qt5 ; then
-		CMAKE_USE_DIR="${WORKDIR}/monero-gui-${PV}"
-		BUILD_DIR="${WORKDIR}/monero-gui-${PV}_build"
-		S="${CMAKE_USE_DIR}" PATCHES="${PATCHES_MONERO_GUI[@]}" cmake_src_prepare
-
-		sed -i \
-			-e "s/@@PV@@/${PV}/" \
-			"${WORKDIR}/monero-gui-${PV}/cmake/VersionGui.cmake" \
-			|| die
-	fi
-}
-
-src_configure() {
-	local mycmakeargs
-	local cmakeargs_monero=(
-		-DBUILD_TAG="$(tc-arch)"
-		-DUSE_CCACHE=OFF
-		-DPYTHON_EXECUTABLE="${PYTHON}"
-		-DBUILD_DOCUMENTATION="$(usex doc ON OFF)"
-		-DBUILD_TESTS=OFF
-		-DCOVERAGE=OFF
-		-DUSE_READLINE="$(usex readline ON OFF)"
-		-DBUILD_GUI_DEPS="$(usex qt5 ON OFF)"
-		-DINSTALL_VENDORED_LIBUNBOUND=OFF
-		-DBUILD_SHARED_LIBS=OFF
-		-DMANUAL_SUBMODULES=ON
-	)
-
-	if use cpu_flags_arm_aes || use cpu_flags_x86_aes ; then
-		cmakeargs_monero+=( -DNO_AES=OFF )
-	else
-		cmakeargs_monero+=( -DNO_AES=ON )
-	fi
-
-	local cmakeargs_monerogui=(
-		"${cmakeargs_monero[@]}"
-		-DUSE_DEVICE_TREZOR="$(usex smartcard ON OFF)"
-		-DENABLE_PASS_STRENGTH_METER=ON
-		-DWITH_SCANNER=ON
-		-DDEV_MODE=OFF
-	)
-
-	export DATABASE="lmdb"
-	export DEVELOPER_LOCAL_TOOLS=0
-	export DEVELOPER_LIBUNBOUND_OLD=0
-
-	CMAKE_USE_DIR="${WORKDIR}/monero-${PV}"
-	BUILD_DIR="${WORKDIR}/monero-${PV}_build"
-	mycmakeargs=( ${cmakeargs_monero[@]} )
-	cmake_src_configure
-
-	if use qt5 ; then
-		CMAKE_USE_DIR="${WORKDIR}/monero-gui-${PV}"
-		BUILD_DIR="${WORKDIR}/monero-gui-${PV}_build"
-		mycmakeargs=( ${cmakeargs_monerogui[@]} )
-		cmake_src_configure
-	fi
-}
-
-src_compile() {
-	CMAKE_USE_DIR="${WORKDIR}/monero-${PV}"
-	BUILD_DIR="${WORKDIR}/monero-${PV}_build"
-	cmake_src_compile
-
-	if use qt5 ; then
-		emake -C "${WORKDIR}/monero-gui-${PV}/src/zxcvbn-c"
-
-		CMAKE_USE_DIR="${WORKDIR}/monero-gui-${PV}"
-		BUILD_DIR="${WORKDIR}/monero-gui-${PV}_build"
-		cmake_src_compile
-	fi
-}
-
-src_install() {
-	CMAKE_USE_DIR="${WORKDIR}/monero-${PV}"
-	BUILD_DIR="${WORKDIR}/monero-${PV}_build"
-	cmake_src_install
-
-	if use qt5 ; then
-		CMAKE_USE_DIR="${WORKDIR}/monero-gui-${PV}"
-		BUILD_DIR="${WORKDIR}/monero-gui-${PV}_build"
-		cmake_src_install
-	fi
-
-	rm -rf "${ED}/usr/include" || die
-	rm -rf "${ED}/usr/lib" || die
-
-	insinto /etc
-	doins utils/conf/monerod.conf
-
-	newinitd "${FILESDIR}/monerod.initd" monerod
-	systemd_dounit utils/systemd/monerod.service
-}