1 files changed, 95 insertions, 0 deletions
diff --git a/net-p2p/monero/monero-0.14.1.2.ebuild b/net-p2p/monero/monero-0.14.1.2.ebuild
new file mode 100644
index 00000000..f56e3f23
--- /dev/null
+++ b/net-p2p/monero/monero-0.14.1.2.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{3_6,3_7} )
+inherit cmake-utils user systemd python-r1
+
+DESCRIPTION="Secure, private, untraceable cryptocurrency"
+HOMEPAGE="https://getmonero.org"
+
+TREZOR_COMMON_COMMIT="31a0073c62738827b48d725facd3766879429124"
+SRC_URI="https://github.com/monero-project/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	smartcard? ( https://github.com/trezor/trezor-common/archive/${TREZOR_COMMON_COMMIT}.tar.gz -> trezor-common-${TREZOR_COMMON_COMMIT}.tar.gz )"
+
+LICENSE="NEWLIB"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="doc qt5 readline smartcard unwind"
+
+RDEPEND="dev-db/lmdb
+	net-dns/unbound:=[threads]
+	net-libs/miniupnpc:=
+	dev-libs/openssl:0
+	>=dev-libs/boost-1.62:=[threads,nls,icu]
+	net-libs/zeromq:=[sodium]
+	net-libs/cppzmq:=
+	dev-libs/rapidjson:=
+	net-libs/openpgm:=
+	readline? ( sys-libs/readline:= )
+	unwind? ( sys-libs/libunwind[lzma] )
+	smartcard? (
+		dev-libs/hidapi:=
+		virtual/libusb:=
+		dev-libs/protobuf:=
+		dev-python/protobuf-python:=[${PYTHON_USEDEP}]
+	)"
+DEPEND="${PYTHON_DEPS}
+	>=dev-util/cmake-3.5
+	doc? (
+		media-gfx/graphviz
+		app-doc/doxygen:0
+	)
+	${RDEPEND}"
+PDEPEND="qt5? ( net-p2p/monero-gui )"
+
+PATCHES=(
+	"${FILESDIR}/${PV}-Drop-in-tree-miniupnpc.patch"
+	"${FILESDIR}/${PV}-Use-gentoo-versioning.patch"
+	"${FILESDIR}/${PV}-Do-not-install-trezor-dep-libs.patch"
+)
+
+CMAKE_BUILD_TYPE=Release
+
+pkg_setup() {
+	enewgroup monero
+	enewuser monero -1 -1 /var/lib/monero monero
+}
+
+src_unpack() {
+	default
+
+	if use smartcard ; then
+		unpack "trezor-common-${TREZOR_COMMON_COMMIT}.tar.gz"
+
+		rm -r "${S}/external/trezor-common" || die
+		mv "trezor-common-${TREZOR_COMMON_COMMIT}" "${S}/external/trezor-common" || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_DOCUMENTATION="$(usex doc ON OFF)"
+		-DBUILD_TESTS=OFF
+		-DCOVERAGE=OFF
+		-DUSE_READLINE="$(usex readline ON OFF)"
+		-DBUILD_GUI_DEPS="$(usex qt5 ON OFF)"
+		-DINSTALL_VENDORED_LIBUNBOUND=OFF
+		-DMANUAL_SUBMODULES=ON
+	)
+
+	export DATABASE="lmdb"
+	export DEVELOPER_LOCAL_TOOLS=0
+	export DEVELOPER_LIBUNBOUND_OLD=0
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	insinto /etc
+	doins utils/conf/monerod.conf
+
+	systemd_dounit utils/systemd/monerod.service
+}