path: root/x11-misc/entrance/entrance-9999.ebuild

# Copyright 2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7
inherit git-r3 meson

DESCRIPTION="An EFL based display manager"
HOMEPAGE="https://github.com/Obsidian-StudiosInc/entrance"
EGIT_REPO_URI="https://github.com/Obsidian-StudiosInc/entrance.git"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS=""
IUSE="nls +pam systemd xcb X"

DEPEND=">=dev-libs/efl-1.19.0[systemd?,X?]
	pam? ( sys-libs/pam )
	systemd? ( sys-apps/systemd )
	xcb? ( x11-libs/libxcb )
	"
RDEPEND="${DEPEND}
	X? (
		x11-apps/sessreg
		x11-apps/xauth
		x11-base/xorg-server
	)
	acct-user/entrance"

src_prepare() {
	# LFS
	sed -i \
		-e '/lockfile/ s|string: .*|string: "/run/entrance.pid";|' \
		-e '/xauth_file/ s|string: .*|string: "/run/entrance.auth";|' \
		data/entrance.conf.in \
		|| die

	# Default user
	sed -i \
		-e '/start_user/ s|string: .*|string: "entrance";|' \
		data/entrance.conf.in \
		|| die

	# Ensure first VT is used
	sed -i \
		-e '/vtnr/ s|ushort: .*|ushort: 1;|' \
		data/entrance.conf.in \
		|| die

	if use systemd ; then
		sed -i \
			-e '/reboot/ s|string: .*|string: "/usr/bin/systemctl reboot";|' \
			-e '/shutdown/ s|string: .*|string: "/usr/bin/systemctl poweroff";|' \
			-e '/suspend/ s|string: .*|string: "/usr/bin/systemctl suspend";|' \
			data/entrance.conf.in \
			|| die
	fi

	default
}

src_configure() {
	local emesonargs=(
		-Dconsolekit=false
		$(meson_use nls)
		$(meson_use pam)
		$(meson_use systemd logind)
	)

	meson_src_configure
}

src_install() {
	meson_src_install
}