path: root/sys-auth/poldi/poldi-0.4.1.ebuild

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7
inherit autotools flag-o-matic pam

DESCRIPTION="PAM module implementing authentication via OpenPGP smartcards"
HOMEPAGE="https://www.gnupg.org/"
SRC_URI="mirror://gnupg/alpha/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="usb"

DEPEND="dev-libs/libgcrypt:=
	sys-libs/pam
	>=dev-libs/libgpg-error-0.7
	usb? ( virtual/libusb:= )"
RDEPEND="${DEPEND}"

PATCHES=(
	"${FILESDIR}/${PV}-debian-specific.patch"
	"${FILESDIR}/${PV}-New-entry--opt_quiet.patch"                # Sat, 17 Jan 2009 17:19:51 +0000
	"${FILESDIR}/${PV}-tests-GPG_ERROR_LIBS-LIBGCRYPT_LIBS.patch" # Sat, 16 May 2009 14:46:01 +0000
	"${FILESDIR}/${PV}-Fixed-log-file-path.patch"                 # Sat, 8 Aug 2009 15:02:51 +0000
	"${FILESDIR}/${PV}-scdaemon-program-Change-patch.diff"        # Wed, 30 Apr 2014 16:39:29 +0900
	"${FILESDIR}/${PV}-Add-scdaemon.conf-installation.patch"      # Wed, 30 Apr 2014 16:43:03 +0900
	"${FILESDIR}/${PV}-Use-LDFLAGS-and-GCC.patch"                 # Wed, 30 Apr 2014 17:15:11 +0900
	"${FILESDIR}/${PV}-Bug-fix-use--loghandle.patch"              # Wed, 30 Apr 2014 17:15:59 +0900
)

src_prepare() {
	default

	eautoreconf
}

src_configure() {
	econf --with-pam-module-directory=$(getpam_mod_dir)

	append-cflags '-DGNUPG_DEFAULT_SCD=\"/usr/libexec/scdaemon\"'
}

src_compile() {
	emake CFLAGS="${CFLAGS}"
}

src_install() {
	emake DESTDIR="${ED}" install install-conf-skeleton

	dodoc AUTHORS ChangeLog MIGRATION NEWS README THANKS TODO
}