cmake: merge libs via virtual object libraries

CMake issued a warming about policy CMP0026: access of LOCATION
target property at config time was disallowed. Offending code
was the code that merged static libraries to generate
libwallet_merged.a.

This patch does that same merge task in a much simpler way. And,
since it doesn't violate the policy, the warning went away.

3 files changed, 12 insertions, 78 deletions

diff --git a/cmake/MergeStaticLibs.cmake b/cmake/MergeStaticLibs.cmake
deleted file mode 100644
index 1f0cee11a..000000000
--- a/cmake/MergeStaticLibs.cmake
+++ /dev/null
@@ -1,74 +0,0 @@
-#    Copyright (C) 2012 Modelon AB
-
-#    This program is free software: you can redistribute it and/or modify
-#    it under the terms of the BSD style license.
-
-#    This program is distributed in the hope that it will be useful,
-#    but WITHOUT ANY WARRANTY; without even the implied warranty of
-#    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
-#    FMILIB_License.txt file for more details.
-
-#    You should have received a copy of the FMILIB_License.txt file
-#    along with this program. If not, contact Modelon AB <http://www.modelon.com>.
-
-# Merge_static_libs(outlib lib1 lib2 ... libn) merges a number of static
-# libs into a single static library
-function(merge_static_libs outlib )
-	set(libs ${ARGV})
-	list(REMOVE_AT libs 0)
-	list(REMOVE_DUPLICATES libs) # just in case
-
-	# First get the file names of the libraries to be merged
-	foreach(lib ${libs})
-		get_target_property(libtype ${lib} TYPE)
-		if(NOT libtype STREQUAL "STATIC_LIBRARY")
-			message(FATAL_ERROR "merge_static_libs can only process static libraries")
-		endif()
-		set(libfiles "${libfiles} $<TARGET_FILE:${lib}>")
-	endforeach()
-
-	if(MSVC) # lib.exe does the merging of given a list
-		set_target_properties(${outlib} PROPERTIES STATIC_LIBRARY_FLAGS "${libfiles}")
-
-	elseif(APPLE) # Use OSX's libtool to merge archives
-		add_custom_command(TARGET ${outlib} POST_BUILD
-			COMMAND rm "$<TARGET_FILE:${outlib}>"
-			COMMAND /usr/bin/libtool -static -o "$<TARGET_FILE:${outlib}>" ${libfiles})
-
-	else() # general UNIX: use "ar" to extract objects and re-add to a common lib
-		foreach(lib ${libs})
-			set(objlistfile ${lib}.objlist) # list of objects in the input library
-			set(objdir ${lib}.objdir)
-
-			add_custom_command(OUTPUT ${objdir}
-				COMMAND ${CMAKE_COMMAND} -E make_directory ${objdir})
-
-			add_custom_command(OUTPUT ${objlistfile}
-				COMMAND ${CMAKE_AR} -x "$<TARGET_FILE:${lib}>"
-				COMMAND ${CMAKE_AR} -t "$<TARGET_FILE:${lib}>" > ../${objlistfile}
-				DEPENDS ${lib} ${objdir}
-				WORKING_DIRECTORY ${objdir})
-
-			# Empty dummy source file that goes into merged library
-			set(mergebase ${lib}.mergebase.c)
-			add_custom_command(OUTPUT ${mergebase}
-				COMMAND ${CMAKE_COMMAND} -E touch ${mergebase}
-				DEPENDS ${objlistfile})
-
-			list(APPEND mergebases "${mergebase}")
-		endforeach()
-
-		# We need a target for the output merged library
-		add_library(${outlib} STATIC ${mergebases})
-		set(outlibfile "$<TARGET_FILE:${outlib}>")
-
-		foreach(lib ${libs})
-			add_custom_command(TARGET ${outlib} POST_BUILD
-				COMMAND ${CMAKE_AR} ru ${outlibfile} @"../${objlistfile}"
-				WORKING_DIRECTORY ${objdir})
-		endforeach()
-
-		add_custom_command(TARGET ${outlib} POST_BUILD
-			COMMAND ${CMAKE_RANLIB} ${outlibfile})
-	endif()
-endfunction()
diff --git a/src/CMakeLists.txt b/src/CMakeLists.txt
index 70bb215d0..5a79325ef 100644
--- a/src/CMakeLists.txt
+++ b/src/CMakeLists.txt
@@ -82,8 +82,13 @@ function (bitmonero_add_library name)
     FILES
       ${ARGN})
 
-  add_library("${name}"
-    ${ARGN})
+  # Define a ("virtual") object library and an actual library that links those
+  # objects together. The virtual libraries can be arbitrarily combined to link
+  # any subset of objects into one library archive. This is used for releasing
+  # libwallet, which combines multiple components.
+  set(objlib obj_${name})
+  add_library(${objlib} OBJECT ${ARGN})
+  add_library("${name}" STATIC $<TARGET_OBJECTS:${objlib}>)
   set_property(TARGET "${name}"
     PROPERTY
       FOLDER "libs")
diff --git a/src/wallet/CMakeLists.txt b/src/wallet/CMakeLists.txt
index c4585f9ee..48e4b0a23 100644
--- a/src/wallet/CMakeLists.txt
+++ b/src/wallet/CMakeLists.txt
@@ -27,7 +27,6 @@
 # THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 
 # include (${PROJECT_SOURCE_DIR}/cmake/libutils.cmake)
-include (${PROJECT_SOURCE_DIR}/cmake/MergeStaticLibs.cmake)
 
 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
 
@@ -76,7 +75,11 @@ target_link_libraries(wallet
     ${EXTRA_LIBRARIES})
 
 set(libs_to_merge wallet cryptonote_core mnemonics common crypto)
-merge_static_libs(wallet_merged "${libs_to_merge}")
+
+foreach(lib ${libs_to_merge})
+    list(APPEND objlibs $<TARGET_OBJECTS:obj_${lib}>) # matches naming convention in src/CMakeLists.txtA
+endforeach()
+add_library(wallet_merged STATIC ${objlibs})
 install(TARGETS wallet_merged
     ARCHIVE DESTINATION lib)