# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8
DB_VER="5.3"
inherit db-use flag-o-matic bash-completion-r1 autotools

DESCRIPTION="P2P Internet currency favored by Shiba Inus worldwide"
HOMEPAGE="http://www.dogecoin.com"
SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE="+dbus +qrcode +qt5 +upnp +utils +wallet"

RDEPEND="
	dev-libs/openssl:0
	>=dev-libs/boost-1.60.0[threads(+)]
	qrcode? ( media-gfx/qrencode )
	qt5? (
		dev-qt/qtgui:5
		dev-qt/qtnetwork:5
		dev-qt/qtwidgets:5
		dev-qt/qtprintsupport:5
		dbus? ( dev-qt/qtdbus:5 )
	)
	upnp? ( net-libs/miniupnpc:0 )
	wallet? ( sys-libs/db:$(db_ver_to_slot ${DB_VER})[cxx] )
	dev-libs/protobuf:=
	dev-libs/libevent:=
	net-libs/cppzmq:=
	dev-libs/univalue:=
"
DEPEND="${RDEPEND}
	qt5? ( dev-qt/linguist-tools:5 )"

PATCHES=(
	"${FILESDIR}/${PV}-test-include-deque.patch"
	"${FILESDIR}/${PV}-Remove-Q_FOREACH.patch"
)

src_prepare () {
	default

	append-cppflags "-I$(db_includedir ${DB_VER})"
	eautoreconf
}

src_configure() {
	local my_econf=(
		--with-daemon
		--with-zmq
		--with-system-univalue
		--enable-man
		--disable-hardening
		--disable-bench
		--disable-extended-rpc-tests
		--disable-gui-tests
		$(use_with utils)
		$(use_enable wallet)
		$(use_enable upnp miniupnpc) $(use_with upnp miniupnpc)
		$(use_with qrcode qrencode)
	)

	if use qt5 ; then
		my_econf+=( --with-gui=qt5 )
	else
		my_econf+=( --with-gui=no )
	fi

	econf \
		"${my_econf[@]}"
}

src_install() {
	default

	newbashcomp contrib/dogecoind.bash-completion dogecoind
}